<%
' Copyright (C) 1998-2005 CyberStrong Internet Services, Inc. All Rights Reserved
'
' This file has been seeded with unique information at point of sale and
' is traceable to its purchaser.
'
' Your license agreement forbids the removal of this notice.
%>

<!-- #include file="../lib/sShared.asp" -->

<%
'
' Review.asp - Display cart for customer review.
'

' Update the quantity and checked fields of the session shopping cart...

Dim i, iCount, SQL, rstItem, iSubTotal, s
Dim SplitArgs		' Holds the result of a split() call
Dim Description		' The short or expanded product description
Dim Status			' Status of user exit
Dim ReturnValue		' Return value from user exit
'Dim FormErrorMsg	' Holds errors for later form display
Dim MinQtyErrorMsg  ' Holds errors for minimum quantity violations
Dim iPass			' 1 for first load, 2 for refresh
Dim ButtonPress		' The button pressed causing this load

' Lock cart out for maintenance ...
 
If (isLocked() Or (Not isDataBaseCurrent())) Then
	Call DisplayMaintPage()
	Response.End
End If


' GetFieldData() - Get field value from form ...

Public Function GetFieldData(ByVal FieldName, ByVal DemoValue)
	Select Case True
		Case (gblDemoMode AND iPass = 1) : GetFieldData = DemoValue
		Case Else                        : GetFieldData = Request.Form(FieldName)
	End Select
End Function


' UpdateCart() - Adjust quantities, remove deleted items.

Public Sub UpdateCart ()
	Dim i, x, n, Quantity, UnitPrice

	' This and next loop may not be combined, quantity changes
	' will be lost.

	If (iPass = 2) Then
		' Adjust quantities, write-in prices, mark deleted items, total cart ...

		For i = 1 to iCount       

			Quantity = Request("Quantity" & CStr(i))
			If IsNumeric(Quantity) Then
				aryCart(cartItemQuantity, i) = abs(CSng(Quantity))
			Else
				aryCart(cartItemQuantity, i) = CSng(1)
			End If

			If (cstAmountEditEnabled) Then
				UnitPrice = Replace(Request("UnitPrice" & CStr(i)), "$", "")
				If IsNumeric(UnitPrice) Then
					aryCart(cartUnitPrice, i) = abs(CDbl(UnitPrice))
				End If
			End If

			aryCart(cartTotalPrice, i) = aryCart(cartUnitPrice, i) * _
											aryCart(cartItemQuantity, i)

			' Flag user checked and discount line items for deletion ...

			If (Request.Form("Keep" & CStr(i)) <> "y") Then
				aryCart(cartDeleted, i) = "y"
			End If

		Next

	End If ' (iPass = 2)


	' Remove deleted items, slide following items down in array ...
	
	For i = 1 to iCount
		
		If ((aryCart(cartDeleted, i) = "y") OR _
			(CStr(aryCart(cartItemQuantity, i)) = "0") OR _
			(CStr(aryCart(cartItemType, i)) = "dsc")   OR _
			(CStr(aryCart(cartItemType, i)) = "cpn")) Then
			
			iCount = iCount - 1
			
			For x = 1 to UBound(aryCart, 1)
				aryCart(x, i) = ""
			Next
			
			n = i
			While n < UBound(aryCart, 2)
				For x = 1 to UBound(aryCart, 1)
					aryCart(x, n)     = aryCart(x, n + 1)
					aryCart(x, n + 1) = ""
				Next
				n = n + 1
			Wend	
			
			i = i - 1
		End If
	
    Next
	
	' Add earned discounts to cart ...
	If (IsInstalled("Feature:Discounts") AND cstDiscountsEnabled) Then
		FeatureInstalled("Feature:Discounts").AddToCart()
	End If
	
	' Add coupons tendered to cart ...
	If (IsInstalled("Feature:Coupons") AND cstCouponsEnabled) Then
		FeatureInstalled("Feature:Coupons").AddToCart()
	End If
	
	' User exit for pricing and quantity adjustment ...
	Status = UserExit(usrAdjustCart, Conn, 0, 0, 0, ReturnValue)
	
	' Save values to Session ...
	Session(sesShoppingCart) = aryCart
	Session(sesItemCount)    = iCount
	
	
End Sub


' CheckMinQtys() - Check cart for mininum item requirements,
'                  Summarize order by product accross options
'                  to meet qty requirement ...
                   

Public Sub CheckMinQtys()
	Dim lstItems, aryProductList, aryQtyInfo(2), aryTemp, Key, aryKeys

	' Omit check for min qty if this feature is disabled ...
	If (Not cstMinOrderQtyEnabled) Then
		Exit Sub
	End If

	' Indexes for aryQtyInfo()
	
	Const idxMinQty   = 0
	Const idxTotalQty = 1
	Const idxOptions  = 2

	' Build a summary of all products in the cart by qty ...
	
	set lstItems = Server.CreateObject("Scripting.Dictionary")
	MinQtyErrorMsg = ""
	
	For i = 1 to iCount
	
		' If this product exists in the dictionary, add
		' customers order qty to it, otherwise, create this
		' product in the dictionary.
		
		Key = aryCart(cartProductCode, i)

		If (lstItems.Exists(Key)) Then
			aryTemp                 = lstItems.Item(Key)
			aryTemp(idxTotalQty)    = aryTemp(idxTotalQty) + CSng(aryCart(cartItemQuantity, i))
			lstItems.Item(Key)      = aryTemp
		Else
			aryQtyInfo(idxMinQty)   = CSng(aryCart(cartMinQuantity, i))
			aryQtyInfo(idxTotalQty) = CSng(aryCart(cartItemQuantity, i))
			aryQtyInfo(idxOptions)  = aryCart(cartOptions, i)

			lstItems.Add Key, aryQtyInfo
		End If

	Next

	' Cycle through summary, check min qtys ...
	
	aryKeys = lstItems.Keys

	For i = 0 To (lstItems.Count - 1)
		If (lstItems.Item(aryKeys(i))(idxTotalQty) < lstItems.Item(aryKeys(i))(idxMinQty)) Then
			MinQtyErrorMsg = MinQtyErrorMsg & _
				"<SPAN CLASS=styFormErrMsg> " & _
				"<B>The minimum order quantity for product " & aryKeys(i) & " is " & _
				lstItems.Item(aryKeys(i))(idxMinQty) & ".<BR></SPAN>"
		End If
	Next

	' Force purchase of minimum qtys on items that have no options ...
	
	For i = 1 to iCount
		If (aryCart(cartOptions, i) = "") Then
			If (CSng(aryCart(cartItemQuantity, i)) < CSng(aryCart(cartMinQuantity, i))) Then
				aryCart(cartItemQuantity, i) = aryCart(cartMinQuantity, i)
			End If
		End If
	Next

	' Clear the dictionary ...
	lstItems.RemoveAll

	' Release objects ...
	set lstItems = Nothing

End Sub


' CalculateSubTotal() - Calculate subtotal to iSubTotal ...

Public Sub CalculateSubTotal()
		iSubTotal = 0
		For i = 1 to iCount       
			If ((aryCart(cartUnitPrice,i)) <> "") Then
				iSubTotal = iSubtotal + aryCart(cartTotalPrice, i)
			End If
		Next
		
		iSubTotal = IIF(iSubTotal < 0, 0, iSubTotal)
End Sub


' DisplayButtons() - Display action buttons ...

Public Sub DisplayButtons()
	Dim rs
	
	If (iCount < MaxShoppingCartItems) Then
		set rs = Server.CreateObject("ADODB.Recordset")
		rs.Open "Products", Conn, adOpenKeyset, adLockOptimistic
		
		If (rs.RecordCount <> 1) Then
			wl("<INPUT TYPE=Image src='custom/images/ConShop.gif' name='btnContinue' alt='Continue Shopping' border=0>&nbsp;&nbsp;")
		End If
		
		rs.Close
		set rs = Nothing
	End If

	If (iCount > 0) Then
		wl("<INPUT TYPE=Image src='custom/images/ReCalc.gif' name='btnRecalculate' alt='Recalculate Totals' border=0>&nbsp;&nbsp;")
	End If

	wl("<INPUT TYPE=Image src='custom/images/CanOrd.gif' name='btnCancelOrder' alt='Cancel Order' border=0>&nbsp;&nbsp;")

	If (iCount > 0) Then
		wl("<INPUT TYPE=Image src='custom/images/CheckOut.gif' name='btnCheckOut' alt='Check Out' border=0>&nbsp;&nbsp;")
	End If
	
End Sub


' ProductHasOptions() - Returns True if the given product code has options,
'						Considers shared options as well.

Public Function ProductHasOptions(ByVal argProductCode)
	Dim rs, SQL
	
	ProductHasOptions = False
	
	' Direct options ...
	If (isOptionsAvail(GetURLValue("ProductCode"))) Then
		ProductHasOptions = True
		Exit Function
	End If
	
	If (cstSharedOptionsEnabled) Then
		' Shared options ...
		Set rs = Server.CreateObject("ADODB.Recordset")
		SQL = "SELECT OptionsUseProductCode FROM Products  " & _
			  "WHERE ({fn UCASE(ProductCode)} = '" & CleanSQL(Ucase(argProductCode), "a") & "')"
		
		rs.Open SQL, Conn, adOpenKeyset, adLockOptimistic
		
		If (rs.RecordCount <> 0) Then
			If (isOptionsAvail(rs("OptionsUseProductCode"))) Then
				ProductHasOptions = True
			End If
		End If
		
		rs.Close : Set rs = Nothing
	End If
End Function


' isOptionsAvail() - Returns True if options are available and active for the given product code.

Public Function isOptionsAvail(ByVal argProductCode)
	Dim rs, SQL
	
	SQL = "SELECT DISTINCT Options.TypeID, OptionTypes.Active FROM Options " & _
		"INNER JOIN OptionTypes ON Options.TypeID = OptionTypes.ID " & _
		"WHERE ({fn LCASE(OptionTypes.Active)} <> 'no') AND " & _
		"      ({fn UCASE(Options.ProductCode)} = '" & CleanSQL(Ucase(argProductCode), "a") & "') " & _
		"ORDER BY TypeID"
	
	set rs = Server.CreateObject("ADODB.Recordset")
	rs.Open SQL, Conn, adOpenKeyset, adLockOptimistic
	
	isOptionsAvail = CBool(rs.RecordCount <> 0)
	
	rs.Close : Set rs = Nothing
End Function


' Main: ---------------------------------------------------------------------------------

FormErrorMsg = ""
iPass = 1

' Need this here, in the event that the 10Browse.asp module is not being used ...
If (Session(sesInit) = "") Then
	Session("OrderID")  = 0      ' For passing to thank you screen
	Session(sesInit)    = "True" ' Confirms that we are started
End If

' Create shopping cart if necessary ...
Call crtCreate()

' Confirm no session timeout ...
Call ConfirmSessionOk(sesItemCount)

' Recover session variables ...
If (Session(sesItemCount) <> "") Then
	iCount  = Session(sesItemCount)
	aryCart = Session(sesShoppingCart)
	
End If

' Record customer's IP address and language now,
' as this info may be lost when the cart goes secure ...
Session("REMOTE_ADDR")          = Request.ServerVariables("REMOTE_ADDR")
Session("HTTP_ACCEPT_LANGUAGE") = Request.ServerVariables("HTTP_ACCEPT_LANGUAGE")


' Open the database ...
Set Conn = dbOpen("rwl")

iPass = IIF(Request.Form("isFormPost") = "True", 2, 1)

Call UpdateCart()
Call CheckMinQtys()

' Process form events -------------------------------------------------

ButtonPress = LCase(GetFormAction())

SELECT CASE True

	CASE ButtonPress = "continue"
		If (FormErrorMsg = "") Then
			Session(sesShoppingCart) = aryCart
			Session(sesItemCount)    = iCount
			
			s = OurSession("ReturnTo")
			OurSession("ReturnTo") = ""
			
			If ((s <> "") AND (LCase(Left(s, 10)) <> "msetup.asp")) Then
				dbClose(Conn)
				Response.Redirect(s)
			Else
				OurSession("txtCategory")     = Request.Form("txtCategory")
				OurSession("txtSearchString") = Trim(Request.Form("txtSearchString"))
				dbClose(Conn)
				Response.Redirect(cstBrowseStartPageURL)
			End If
		End If

		Call UpdateCart()
		Call CheckMinQtys()


	CASE ButtonPress = "recalculate"
		Session(sesShoppingCart) = aryCart
		Session(sesItemCount)    = iCount


	CASE ButtonPress = "cancelorder"
		dbClose(Conn)
		Session.Abandon
		Response.Redirect(cstCancelURL)


	CASE ButtonPress = "agree"
		dbClose(Conn)
		Response.Redirect("30GetCst.asp")

	CASE ButtonPress = "checkout"
		Call CalculateSubTotal()

		
		If (CDbl(iSubTotal) < CDbl(cstMinOrderAmount)) Then
			FormErrorMsg = FormErrorMsg & _
			 "<SPAN CLASS=styFormErrMsg> " & _
			 	"<B>The minimum order for checkout is " & _
			 	OurFormatCurrency(cstMinOrderAmount) & ".<BR></SPAN>"
		End If
		
		If ((FormErrorMsg & MinQtyErrorMsg) = "") Then
			Session(sesItemCount)    = iCount
			Session(sesShoppingCart) = aryCart

			dbClose(Conn)

			If (iCount > 0) Then
				' Display terms and conditions file if exists, or move to 30GetCst.asp ...
				If (FileExists("Terms.htm")) Then
					Call DisplayPageHeader("20", "", "")
					wl("<table width=600 cellpadding=0 cellspacing=0>")
					wl("<tr><td>" & ReadFile("Terms.htm") & "</td></tr>")
					wl("<tr><td align=right>")
						wl("<form method=post name=frmMain action='20Review.asp'>")
						wl("<input type=Image src='custom/images/CanOrd.gif' name='btnCancelOrder' alt='Cancel Order' border=0>&nbsp;&nbsp;")
						wl("<input type=Image src='custom/images/Agree.gif'  name='btnAgree'       alt='I Agree'      border=0>")
						wl("</form>")
					wl("</td></tr></table>")
					Response.End
				Else
					Response.Redirect("30GetCst.asp")
				End If
			Else
				Response.Redirect(cstBrowseStartPageURL)
			End If
		End If


	Case ButtonPress = "viewall"
		OurSession("SelectedCategory")    = ""
		OurSession("BrowseSQL")           = ""
		OurSession("SearchString")        = ""
		OurSession("txtSearchStringLast") = ""
		OurSession("txtCategoryLast")     = ""

		Session(sesItemCount)          = iCount
		Session(sesShoppingCart)       = aryCart

		dbClose(Conn)
		Response.Redirect("10Browse.asp")


	Case (Request.Form("txtCategory") <> OurSession("txtCategoryLast")) AND _
			(Request.Form("txtCategory") <> "")
		OurSession("txtCategory") = Request.Form("txtCategory")
		Session(sesItemCount)     = iCount
		Session(sesShoppingCart)  = aryCart

		dbClose(Conn)
		Response.Redirect("10Browse.asp")


	Case (ButtonPress = "search") OR _
			((Trim(Request.Form("txtSearchString")) <> OurSession("txtSearchStringLast")) AND _
			(Trim(Request.Form("txtSearchString")) <> ""))
		OurSession("txtSearchString") = Trim(Request.Form("txtSearchString"))
		Session(sesItemCount)         = iCount
		Session(sesShoppingCart)      = aryCart

		dbClose(Conn)
		Response.Redirect("10Browse.asp")


	CASE ButtonPress = "go"
		' Note: This is the default button for this form and must
		'       be tested last ...
		
		Session(sesShoppingCart)      = aryCart
		Session(sesItemCount)         = iCount
		OurSession("txtCategory")     = Request.Form("txtCategory")
		OurSession("txtSearchString") = Trim(Request.Form("txtSearchString"))
		
		dbClose(Conn)
		Response.Redirect("10Browse.asp")


	Case Else

		' Initial page load ...
		If (GetURLValue("ReturnTo") <> "") Then
			OurSession("ReturnTo") = GetURLValue("ReturnTo")
		End If

		' If a product code was passed, add this product to
		' the current shopping cart
	 
		If (GetURLValue("ProductCode") <> "") Then

			' Check to see if this product has options, if so, send user to 
			' options page to select them. Item will be added to cart on
			' options page so we will won't need to come here again.
			
			If (ProductHasOptions(GetURLValue("ProductCode"))) Then
				dbClose(Conn)
				Response.Redirect("10Expand.asp?ProductCode=" & GetURLValue("ProductCode"))
			End If


			' Otherwise, look up data on this product and add it to the cart.
			' vis=1 means that product must not be hidden or out of date range.
			
			If (GetURLValue("vis") =  1) Then
				SQL = ""
				SQL = SQL & "SELECT * FROM Products "
				SQL = SQL & "WHERE "
				
				If (cstDisplayDatesEnabled) Then
					SQL = SQL & "((ProductStartDate Is Null) OR (ProductStartDate <= {fn Now()})) AND "
					SQL = SQL & "((ProductEndDate   Is Null) OR (ProductEndDate   >= {fn Now()})) AND "
				End If
				
				If (cstProductHideEnabled) Then
					SQL = SQL & "{fn LCase(ProductHide)} <> 'yes' AND "
				End If
				
				SQL = SQL & "{fn UCASE(ProductCode)} = '" & Ucase(GetURLValue("ProductCode")) & "' AND "
				SQL = SQL & "(1 = 1) "
				
				If (cstSortCodeEnabled) Then
					SQL = SQL & "ORDER BY ProductSortCode"
				End If
				
			Else
				SQL = "SELECT * FROM Products WHERE {fn UCASE(ProductCode)} = '" & CleanSQL(Ucase(GetURLValue("ProductCode")), "a") & "'"
			End If


			set rstItem = Server.CreateObject("ADODB.Recordset")
			rstItem.Open SQL, Conn, adOpenKeyset, adLockOptimistic

			If (rstItem.RecordCount <> 0) Then
           
				aryCartData(cartProductID)              = rstItem("ProductID")
				aryCartData(cartProductCode)            = rstItem("ProductCode")
				aryCartData(cartProductName)            = rstItem("ProductName")
				aryCartData(cartProductDescription)     = rstItem("ProductDescription")
				aryCartData(cartProductDescriptionLong) = rstItem("ProductDescriptionLong")
				aryCartData(cartCategory)               = rstItem("ProductCategory")
				aryCartData(cartCoupons)                = rstItem("ProductCoupons")
				aryCartData(cartProductShipsFree)       = rstItem("ProductShipsFree")
				aryCartData(cartShippingUnits)          = rstItem("ShippingUnits")
				aryCartData(cartUnitPrice)              = rstItem("UnitPrice")
				aryCartData(cartOptions)                = ""
				aryCartData(cartDiscountName )          = rstItem("DiscountName")
				aryCartData(cartDownloadFileName)       = rstItem("DownloadFileName")
				aryCartData(cartAllowAmountEdit)        = rstItem("AllowAmountEdit")
				aryCartData(cartTaxOverride)			= rstItem("TaxOverride")
				aryCartData(cartNotes)					= rstItem("Notes")
                aryCartData(cartNSN)					= rstItem("NSN")
				aryCartData(cartPackaging)				= rstItem("Packaging")
				aryCartData(cartSKU)					= rstItem("SKU")
'************coded inserted august 29,2005**********start
'				aryCartData(larryNotes)					= rstItem("StampParams")
'************coded inserted august 29,2005**********end
				
				If (cstSalePriceEnabled AND (Not IsNullOrZero(rstItem("SalePrice")))) Then
					aryCartData(cartUnitPrice)          = rstItem("SalePrice")
				Else
					if session("Organization") = "Federal" then
					aryCartData(cartUnitPrice)          = rstItem("FedSalePrice")
					elseif session("Organization") = "State" then
					aryCartData(cartUnitPrice)          = rstItem("StateSalePrice")
					elseif session("Organization") = "Reseller" then
					aryCartData(cartUnitPrice)          = rstItem("ResellerSalePrice")
					elseif session("Organization") = "Local Government" then
					aryCartData(cartUnitPrice)          = rstItem("LocalGovSalePrice")
					elseif session("Organization") = "Corporation" then
					aryCartData(cartUnitPrice)          = rstItem("CorporationSalePrice")
					else 
					aryCartData(cartUnitPrice)          = rstItem("UnitPrice")
					End if
				End If

				If (cstMinOrderQtyEnabled AND (Not IsNull(rstItem("MinQty")))) Then
					aryCartData(cartItemQuantity)       = rstItem("MinQty")
					aryCartData(cartMinQuantity)        = rstItem("MinQty")
				Else
					aryCartData(cartItemQuantity)       = 1
					aryCartData(cartMinQuantity)        = 1
				End If

				aryCartData(cartItemType)				= "usr"


				' Add this item to the shopping cart ...
				crtAddToCart(aryCartData)
				
				rstItem.Close : Set rstItem = Nothing
				
			Else

				FormErrorMsg = FormErrorMsg + "<SPAN CLASS=styFormErrMsg>The item you have selected is presently unavailable.<BR></SPAN>"

			End If ' (rstItem.RecordCount <> 0)

		End If ' (GetURLValue("ProductCode") <> "")

		Call UpdateCart()
		Call CheckMinQtys()
		
End Select


' Calculate the orders total so far ...
Call CalculateSubTotal()

' Save cart ...
Session(sesItemCount)    = iCount
Session(sesShoppingCart) = aryCart


' Write the page ...

wl("<FORM METHOD=POST NAME=frmMain ACTION='20Review.asp'>")

wl("<TABLE CELLPADDING=0 CELLSPACING=0 WIDTH=900 ALIGN=" & cstPagePosition & "><TR><TD>") ' Page position table start ...
Call DisplayPageHeader("20", "", "")
wl("</td><tr><td>&nbsp;</td></tr><tr><td>")
If ((cstDisplayCategoryDDB AND cstCategoriesEnabled) OR cstDisplaySearchBox) Then
	wl("<TABLE WIDTH=900 BORDER=0 CELLPADDING=3 CELLSPACING=0>")

	wl("<TR><TD NOWRAP VALIGN=MIDDLE>")
		Call catDisplayDDB()
		wl("</TD>")
	
		If (cstDisplaySearchBox) Then
			wl("<TD NOWRAP ALIGN=RIGHT VALIGN=MIDDLE>")
				wl("<INPUT type='text' name='txtSearchString' value='" & OurSession("SearchString") & "' size=15 class=styProductSearch>&nbsp;")
				wl("<INPUT TYPE=Image src='custom/images/Search.gif'  name='btnSearch' align='absmiddle' alt='Search' border=0>&nbsp;")
				If (cstViewAllButtonEnabled) Then
					wl("<INPUT TYPE=Image src='custom/images/ViewAll.gif' name='btnViewAll' align='absmiddle' alt='View All' border=0>")
				End If
			wl("</TD>")
		Else
			wl("<TD NOWRAP WIDTH=300>&nbsp;</TD>")
		End If

	wl("</TR></TABLE>")
End If

wl("<TABLE BORDER=0 WIDTH=900>")

	wl("<TR>")
		wl("<TD>")

		' Display errors, if any ...
		
		If ((FormErrorMsg & MinQtyErrorMsg) <> "") Then
			wl("<br>" & FormErrorMsg & MinQtyErrorMsg)
		End If
		
		If (iCount = 0) Then

			wl("<SPAN CLASS=styFormErrMsg><BR>There are no items in your shopping cart.</SPAN>")

		Else
		
			wl("<TABLE CELLPADDING=3 CELLSPACING=0 BORDER=0 WIDTH=900>")

				wl("<TR>")
					wl("<TD ALIGN=LEFT WIDTH='1%'>")
					wl("<SPAN CLASS=styHeading>Code</SPAN>")
					wl("</TD>")

					wl("<TD ALIGN=LEFT WIDTH='96%'>")
					wl("<SPAN CLASS=styHeading>&nbsp;Description</SPAN>")
					wl("</TD>")

					wl("<TD ALIGN=CENTER WIDTH='1%' NOWRAP>")
					wl("<SPAN CLASS=styHeading>Qty</SPAN>")
					wl("</TD>")

					wl("<TD ALIGN=RIGHT WIDTH='1%' NOWRAP>")
					wl("<SPAN CLASS=styHeading>&nbsp;Each</SPAN>")
					wl("</TD>")

					wl("<TD ALIGN=RIGHT WIDTH='1%' NOWRAP>")
					wl("<SPAN CLASS=styHeading>&nbsp;Total</SPAN>")
					wl("</TD>")
				wl("</TR>")


				wl("<TR><TD COLSPAN=5 CLASS=styTabAccentColor><IMG SRC='images/SpaceRow.gif'  HEIGHT=1></TD></TR>")
				wl("<tr><td COLSPAN=5 CLASS=styTabBackColor><IMG SRC='images/SpaceRow.gif' HEIGHT=1></td></tr>")

				' Order detail ...
				
				For i = 1 to iCount

				wl("<TR>")
					' Product code ------------------------------------
					wl("<TD WIDTH='1%' NOWRAP CLASS=styTabBackColor ALIGN=LEFT VALIGN=TOP>")
						If (aryCart(cartItemType, i) = "usr") Then
							Response.Write("<INPUT TYPE='CHECKBOX' CHECKED NAME='Keep" & CStr(i) & "' VALUE='y' CLASS=styGenFieldCheckBox>&nbsp;")
						End If
						If ((aryCart(cartItemType, i) = "usr") And cstLinkExpandOnCheckout) Then

'************coded inserted august 26,2005**********start
if aryCart(larryNotes, i)<>"" then%>
<SPAN CLASS=styProductCodeVal><a href='#' onClick='submitform<%=i%>(); return false;'><%=aryCart(cartProductCode, i)%></a></SPAN><%
else
'************coded inserted august 26,2005**********end

							Response.Write("<SPAN CLASS=styProductCodeVal><a href=""10Expand.asp?ProductCode=" & aryCart(cartProductCode, i) & """>" & aryCart(cartProductCode, i) & "</a></SPAN>")

'************coded inserted august 26,2005**********start
end if
'************coded inserted august 26,2005**********end


						Else
							Response.Write("<SPAN CLASS=styProductCodeVal>" & aryCart(cartProductCode,i) & "</SPAN>")
						End If
					wl("</TD>")

					' Product description ----------------------------
					wl("<TD WIDTH='96%' CLASS=styTabBackColor ALIGN=LEFT VALIGN=MIDDLE>")
						wl("<SPAN CLASS=styProductName>")
						wl(aryCart(cartProductName,i) & "<BR></SPAN><SPAN CLASS=styProductDescShort>")
						Response.Write(GetShortDescription(aryCart(cartProductDescription, i), "")) & "</SPAN>"
'************coded inserted august 27,2005**********start
if aryCart(larryNotes, i)<>"" then%>
<script type="text/javascript"><!--
function submitform<%=i%>(){
	var x=document.frmlarry<%=i%>;
	x.target='';
	x.action='10expand.asp?ProductCode=<%=aryCart(cartProductCode, i)%>&larID=<%=i%>&larEdit=on';
	x.submit();
}
function submitpopuponly<%=i%>(){
	var x=document.frmlarry<%=i%>;
	x.target='larpreview';
	x.action='popupstamp.asp?ProductCode=<%=aryCart(cartProductCode, i)%>';
	x.submit();
}
//--></script>
<%dim larTmp1
larTmp1=""
if aryCart(cartOptions,i)<>"" then
	larTmp1="Nameplate"
else
	larTmp1="Stamp"
end if%><!-- [<%=aryCart(larryNotes, i)%>] -->
<br><SPAN CLASS=styProductCodeVal><a href='#' onClick='submitform<%=i%>(); return false;'>Edit Your <%=larTmp1%></a></SPAN>
| <SPAN CLASS=styProductCodeVal><a href='#'
onClick='popuplar("larpreview"); submitpopuponly<%=i%>(); return false;'>View Your <%=larTmp1%></a></SPAN><%
end if
'************coded inserted august 27,2005**********end

						' Offer discount schedule for viewing if available ...
						If (IsInstalled("Feature:Discounts") AND cstDiscountsEnabled) Then
							FeatureInstalled("Feature:Discounts").WriteLink(i)
						End If

						Response.Write(FormatOptions(aryCart(cartOptions,i)))
					
					wl("</TD>")

					' Quantity ----------------------------------------
					wl("<TD WIDTH='1%' CLASS=styTabBackColor ALIGN=CENTER VALIGN=TOP>")
						If (aryCart(cartItemType, i) = "usr") Then
							wl("<INPUT TYPE=TEXT NAME='Quantity" & CStr(i) & "' VALUE='" & aryCart(cartItemQuantity, i) & "' SIZE=3 MAXLENGTH=4 CLASS=styQtyEdit>")
						Else
							wl("<SPAN CLASS=styQtyVal>" & aryCart(cartItemQuantity, i) & "</SPAN>")
						End If
					wl("</TD>")

					' Unit Price --------------------------------------
					If (cstAmountEditEnabled AND (LCase(Trim(aryCart(cartAllowAmountEdit, i))) = "yes")) Then
						wl("<TD WIDTH='1%' CLASS=styTabBackColor ALIGN=RIGHT VALIGN=TOP NOWRAP>")
						wl("<INPUT TYPE=TEXT NAME='UnitPrice" & CStr(i) & "' VALUE='" & OurFormatCurrency(aryCart(cartUnitPrice,i)) & "' SIZE=10 MAXLENGTH=10 CLASS=styUnitPriceEdit>")
						wl("</TD>")
					Else
						wl("<TD WIDTH='1%' CLASS=styTabBackColor ALIGN=RIGHT VALIGN=TOP>")
						wl("<SPAN CLASS=styUnitPriceVal>" & OurFormatCurrency(aryCart(cartUnitPrice,i)) & "</SPAN>")
						wl("</TD>")
					End If

					' Total Price -------------------------------------
					wl("<TD WIDTH='1%' CLASS=styTabBackColor ALIGN=RIGHT VALIGN=TOP>")
						wl("<SPAN CLASS=styTotalPriceVal>" & OurFormatCurrency(aryCart(cartTotalPrice, i)) & "</SPAN>")
					wl("</TD>")
				wl("</TR>")

				wl("<TR><TD COLSPAN=5 CLASS=styTabBackColor><IMG SRC='images/SpaceRow.gif' HEIGHT=1></TD></TR>")

				Next ' Shopping cart detail line

				' BEGIN subtotal
 				wl("<TR>")
					wl("<TD COLSPAN=3 CLASS=styTabBackColor><IMG SRC='images/SpaceRow.gif' HEIGHT=1></TD>")
					wl("<TD CLASS=styTabBackColor ALIGN=LEFT><SPAN CLASS=stySubTotalTag>Subtotal:</SPAN></TD>")
					wl("<TD CLASS=styTabBackColor ALIGN=RIGHT NOWRAP><SPAN CLASS=stySubTotalVal>" & OurFormatCurrency(iSubtotal) & "</SPAN></TD>")
				wl("</TR>")

			wl("</TABLE>")
		End If ' Else iCount = 0

		' Collect Coupon info from user if installed and enabled ...
		If (IsInstalled("Feature:Coupons") AND cstCouponsEnabled) Then
			FeatureInstalled("Feature:Coupons").GetCouponsFromUser()
		End If

		' Display recommend products (cross selling) if installed and enabled ...
		If (IsInstalled("Feature:Cross Sell") AND cstCrossSellEnabled) Then
			FeatureInstalled("Feature:Cross Sell").Recommend()
		End If

		' Display shipping preview if enabled ...
		If (cstShipPreviewEnabled) Then
			Call DisplayPreviewShippingPanel()
		End If

		wl("<BR>")
		wl("<BR>")
		wl("<CENTER>")
			Call DisplayButtons()
		wl("</CENTER>")

wl("</TD></TR>")

wl("<TR><TD ALIGN=Left><BR>")
	Call DisplayAffiliateLink()
wl("</TD></TR>")

wl("</TABLE>")

wl("</TD></TR></TABLE>") ' Page position table end.

' Used to detect if this load was from a POST or link ...
wl("<input type=hidden name='isFormPost' value='True'>")

wl("</FORM>")

dbClose(Conn)
'************coded inserted august 26,2005**********start
%>
<script type="text/javascript"><!--
var win=null;
function popuplar(windowname) {
 LeftPosition=(screen.width)? (screen.width-800)/2: 100;
 TopPosition=(screen.height)? (screen.height-300)/2: 100;
 settings='width=800,height=300,top='+TopPosition+',left='+LeftPosition+',scrollbars=yes,location=no,directories=no,status=no,menubar=yes,toolbar=no,resizable=yes';
 win=window.open('',windowname,settings);
 win.focus();
 return true;
}
//--></script>
<%
Dim larrycart,arr,arr1,arr2,ilar,jlar,arr3
For ilar = 1 to iCount
	if aryCart(larryNotes, ilar)<>"" then%>
	<form name="frmlarry<%=ilar%>" id="frmlarry<%=ilar%>" method="post" action="10expand.asp?ProductCode=<%=aryCart(cartProductCode, ilar)%>"><%
		larrycart=aryCart(larryNotes, ilar)
		arr=Split(larrycart,"<lar>")
		arr1=Split(arr(0),";")
		Response.Write "<input type=hidden name='larNumTextLines' value='"&arr1(0)&"'>"
		Response.Write "<input type=hidden name='larImageAlignment' value='"&arr1(1)&"'>"
		Response.Write "<input type=hidden name='larNumHorizontalLines' value='"&arr1(2)&"'>"
		Response.Write "<input type=hidden name='larBorder' value='"&arr1(3)&"'>"
		Response.Write "<input type=hidden name='larStampColor' value='"&arr1(4)&"'>"
		Response.Write "<input type=hidden name='larBorderThickness' value='"&arr1(5)&"'>"
		Response.Write "<input type=hidden name='larImageSize' value='"&arr1(6)&"'>"
		Response.Write "<input type=hidden name='larIDcategory' value='"&arr1(7)&"'>"
		Response.Write "<input type=hidden name='larIDclip' value='"&arr1(8)&"'>"
		Response.Write "<input type=hidden name='SuccessUpload' value='"&arr1(9)&"'>"
		arr1=Split(arr(1),";")
		for jlar=Lbound(arr1) to Ubound(arr1)
			arr2=Split(arr1(jlar),":")
			Response.Write "<input type=hidden name='larLineLocation"&jlar+1&"' value='"&arr2(0)&"'>"
			Response.Write "<input type=hidden name='larLineWidth"&jlar+1&"' value='"&arr2(1)&"'>"
			Response.Write "<input type=hidden name='larLineThickness"&jlar+1&"' value='"&arr2(2)&"'>"
			Response.Write "<input type=hidden name='larLineSpaceAbove"&jlar+1&"' value='"&arr2(3)&"'>"
			Response.Write "<input type=hidden name='larLineSpaceBelow"&jlar+1&"' value='"&arr2(4)&"'>"
			Response.Write "<input type=hidden name='larLineAlignment"&jlar+1&"' value='"&arr2(5)&"'>"
		next
		Response.Write "<input type=hidden name='rClipArtFile' value='"&arr(2)&"'>"
		arr1=Split(arr(3),"<r>")
		for jlar=Lbound(arr1) to Ubound(arr1)
			arr2=Split(arr1(jlar),"<y>")
			Response.Write "<input type=hidden name='larText"&jlar+1&"' value='"&arr2(0)&"'>"
			arr3=Split(arr2(1),":")
			Response.Write "<input type=hidden name='larTextFont"&jlar+1&"' value='"&arr3(0)&"'>"
			Response.Write "<input type=hidden name='larTextFontSize"&jlar+1&"' value='"&arr3(1)&"'>"
			Response.Write "<input type=hidden name='larTextFontStyle"&jlar+1&"' value='"&arr3(2)&"'>"
			Response.Write "<input type=hidden name='larTextSpaceAbove"&jlar+1&"' value='"&arr3(3)&"'>"
			Response.Write "<input type=hidden name='larTextSpaceBelow"&jlar+1&"' value='"&arr3(4)&"'>"
			Response.Write "<input type=hidden name='larTextAlignment"&jlar+1&"' value='"&arr3(5)&"'>"
		next
		arr3=Split(arr(4),"<nameplate>")
		if Ubound(arr3)>0 then
			dim tql
			tql=Split(arr3(1),"<tql>")
			Response.Write "<input type=hidden name='mProductID' value='"&arr3(0)&"'>"
			Response.Write "<input type=hidden name='larWidHei' value='"&tql(0)&"'>"
			Response.Write "<input type=hidden name='larWidHei1' value='"&tql(1)&"'>"
			Response.Write "<input type=hidden name='larWidth' value='"&tql(2)&"'>"
			Response.Write "<input type=hidden name='larHeight' value='"&tql(3)&"'>"
		else
			Response.Write "<input type=hidden name='mProductID' value='"&arr(4)&"'>"
		end if
		if UBound(arr)>5 then
			arr1=Split(arr(5),";")
			Response.Write "<input type=hidden name='larNumTextLines2' value='"&arr1(0)&"'>"
			Response.Write "<input type=hidden name='larImageAlignment2' value='"&arr1(1)&"'>"
			Response.Write "<input type=hidden name='larNumHorizontalLines2' value='"&arr1(2)&"'>"
			'Response.Write "<input type=hidden name='larBorder' value='"&arr1(3)&"'>"
			'Response.Write "<input type=hidden name='larStampColor' value='"&arr1(4)&"'>"
			Response.Write "<input type=hidden name='larBorderThickness2' value='"&arr1(5)&"'>"
			Response.Write "<input type=hidden name='larImageSize2' value='"&arr1(6)&"'>"
			Response.Write "<input type=hidden name='larIDcategory2' value='"&arr1(7)&"'>"
			Response.Write "<input type=hidden name='larIDclip2' value='"&arr1(8)&"'>"
			Response.Write "<input type=hidden name='SuccessUpload2' value='"&arr1(9)&"'>"
			arr1=Split(arr(6),";")
			for jlar=Lbound(arr1) to Ubound(arr1)
				arr2=Split(arr1(jlar),":")
				Response.Write "<input type=hidden name='larLineLocation2"&jlar+1&"' value='"&arr2(0)&"'>"
				Response.Write "<input type=hidden name='larLineWidth2"&jlar+1&"' value='"&arr2(1)&"'>"
				Response.Write "<input type=hidden name='larLineThickness2"&jlar+1&"' value='"&arr2(2)&"'>"
				Response.Write "<input type=hidden name='larLineSpaceAbove2"&jlar+1&"' value='"&arr2(3)&"'>"
				Response.Write "<input type=hidden name='larLineSpaceBelow2"&jlar+1&"' value='"&arr2(4)&"'>"
				Response.Write "<input type=hidden name='larLineAlignment2"&jlar+1&"' value='"&arr2(5)&"'>"
			next
			Response.Write "<input type=hidden name='rClipArtFile2' value='"&arr(7)&"'>"
			arr1=Split(arr(8),"<r>")
			for jlar=Lbound(arr1) to Ubound(arr1)
				arr2=Split(arr1(jlar),"<y>")
				Response.Write "<input type=hidden name='larText2"&jlar+1&"' value='"&arr2(0)&"'>"
				arr3=Split(arr2(1),":")
				Response.Write "<input type=hidden name='larTextFont2"&jlar+1&"' value='"&arr3(0)&"'>"
				Response.Write "<input type=hidden name='larTextFontSize2"&jlar+1&"' value='"&arr3(1)&"'>"
				Response.Write "<input type=hidden name='larTextFontStyle2"&jlar+1&"' value='"&arr3(2)&"'>"
				Response.Write "<input type=hidden name='larTextSpaceAbove2"&jlar+1&"' value='"&arr3(3)&"'>"
				Response.Write "<input type=hidden name='larTextSpaceBelow2"&jlar+1&"' value='"&arr3(4)&"'>"
				Response.Write "<input type=hidden name='larTextAlignment2"&jlar+1&"' value='"&arr3(5)&"'>"
			next
			'Response.Write "<input type=hidden name='mProductID' value='"&arr(9)&"'>"
		end if
	end if
%>
<input type="hidden" name="larForm" value="LastForm"><!-- <input type="submit" value="ok"> -->
	</form>
<%
Next
'************coded inserted august 26,2005**********end
%>